import flash.display.Sprite;
import flash.net.URLRequest;
import flash.events.Event;
import fl.video.VideoEvent;
import fl.video.MetadataEvent;
import flash.events.MouseEvent;
import flash.filesystem.*;
import flash.net.FileFilter;
import flash.media.SoundMixer;
import flash.utils.ByteArray;
import flash.utils.Timer;
import flash.desktop.NativeDragManager;
import flash.events.NativeDragEvent;
import flash.desktop.ClipboardFormats;
//criando o objeto File para abrir no desktop (desktopDirectory)
var arquivo:File = File.desktopDirectory;

stage.scaleMode = StageScaleMode.NO_SCALE;
stage.align = StageAlign.TOP_LEFT;
//colocando um smoothing para melhorar a qualidade do video
Controles.video.getVideoPlayer(Controles.video.activeVideoPlayerIndex).smoothing = true;
//quando o video terminar chamar função Terminou
Controles.video.addEventListener(VideoEvent.COMPLETE, Terminou);
Controles.video.seekBar = Controles.mSeekBar;
Controles.video.volumeBar = Controles.mVolumeBar;
Controles.play_p.pause_mc.visible = false;
Controles.mcUrl.visible = false;
Controles.abreVideo.addEventListener(MouseEvent.MOUSE_UP, Abrir);
Controles.abreUrl.addEventListener(MouseEvent.MOUSE_UP, Abrir_url);
this.addEventListener(NativeDragEvent.NATIVE_DRAG_ENTER, dragEnter);
this.addEventListener(NativeDragEvent.NATIVE_DRAG_DROP, dragVideo);
//função para arrastar um video na aplicação
function dragEnter(e:NativeDragEvent){
	var dVideo:Object = e.clipboard.getData(ClipboardFormats.FILE_LIST_FORMAT);
	if (dVideo[0].extension == "flv"){
		NativeDragManager.acceptDragDrop(this);
	}
}
//quando soltar o video na aplicação
function dragVideo(e:NativeDragEvent){
	var dVideo:Object = e.clipboard.getData(ClipboardFormats.FILE_LIST_FORMAT);
	Controles.mcUrl.visible = false;
	Controles.infoVideo.txt_tocando.text = nomeVideo(dVideo[0].name);
	Controles.play_p.pause_mc.visible = true;
	Controles.play_p.buttonMode = true;
	Controles.video.play(dVideo[0].url);
	Controles.video.addEventListener(MetadataEvent.METADATA_RECEIVED, AtualizaTempoTotal);
	stage.addEventListener(Event.ENTER_FRAME, AtualizaTempoCorrido);
}
//redimenciona video
function ResizeVideo(vidWidth:Number, vidHeight:Number){
	Controles.video.width = (vidWidth * 405)/ vidHeight;
	Controles.video.x = (720-Controles.video.width)/2;
	Controles.video.y = (440-Controles.video.height-20)/2;
}
//função Terminou da play no video
function Terminou(e:VideoEvent){
	Controles.video.play();
}
function Abrir(e:MouseEvent){
	//chama a função "Selecionar" com o local do nosso objeto File "arquivo"
	Selecionar(arquivo);
}
function Selecionar(e:File){
	//define os formatos de arquivos permitidos para serem abertos
	var FileF:FileFilter = new FileFilter("Flash Video (*.flv)","*.flv");
	//método browseForOpen abre uma janela para selecionar um arquivo
	e.browseForOpen("Escolha um Vídeo", [FileF]);
	//chama a função "ArquivoSelecionado" que vai executar o video escolhido
	e.addEventListener(Event.SELECT, ArquivoSelecionado);
}
function ArquivoSelecionado(e:Event){
	Controles.mcUrl.visible = false;
	Controles.infoVideo.txt_tocando.text = nomeVideo(arquivo.name);
	Controles.play_p.pause_mc.visible = true;
	Controles.play_p.buttonMode = true;
	Controles.video.play(arquivo.nativePath);
	Controles.video.addEventListener(MetadataEvent.METADATA_RECEIVED, AtualizaTempoTotal);
	stage.addEventListener(Event.ENTER_FRAME, AtualizaTempoCorrido);
}
//abre mcUrl para abrir video com uma url
function Abrir_url(e:MouseEvent){
	Controles.mcUrl.visible = true;
	Controles.mcUrl.txt_url.addEventListener(MouseEvent.CLICK, seleciona_txt);
	Controles.mcUrl.txt_url.addEventListener(KeyboardEvent.KEY_DOWN, abreLink);
	Controles.mcUrl.e_url.addEventListener(MouseEvent.CLICK, abreBtnLink);
}
function seleciona_txt(e:MouseEvent){
	setTimeout(Controles.mcUrl.txt_url.setSelection, 100, 0, e.target.text.length);
}
//quando apertar ENTER com uma url definida chama loadURL
function abreLink(e:KeyboardEvent){
	if (e.charCode == Keyboard.ENTER){
		if(Controles.mcUrl.txt_url.text==""){
			trace("sem URL");
		}else{
			loadURL(e.target.text);
		}
	}
}
function abreBtnLink(e:MouseEvent){
	if(Controles.mcUrl.txt_url.text==""){
		trace("sem URL");
	}else{
		loadURL(Controles.mcUrl.txt_url.text);
	}
}
//loadURL abre o video
function loadURL(e:String){
	Controles.mcUrl.visible = false;
	Controles.infoVideo.txt_tocando.text = nomeVideo(e);
	Controles.play_p.pause_mc.visible = true;
	Controles.play_p.buttonMode = true;
	Controles.video.play(e);
	Controles.video.addEventListener(MetadataEvent.METADATA_RECEIVED, AtualizaTempoTotal);
	stage.addEventListener(Event.ENTER_FRAME, AtualizaTempoCorrido);
}
//fecha mcUrl
Controles.mcUrl.f_url.addEventListener(MouseEvent.MOUSE_UP, fechar_url);
function fechar_url(e:MouseEvent){
	Controles.mcUrl.visible = false;
}
//função para tirar a extensão e/ou endereço do link ficando apenas o "nome" do video
function nomeVideo(s:String):String{
	if (s.lastIndexOf("/") == (s.length - 1)){
		return nomeVideo(s.substring(0, s.length - 1));
	}
	var str:String = s.substring((s.lastIndexOf("/") + 1));
	var ultimo:int = str.indexOf(".");
	if (ultimo == -1){
		if (str.indexOf("?") > -1){
			ultimo = str.indexOf("?");
		}else{
			ultimo = str.length;
		}
	}
	return str.substring(0, ultimo);
}
//Atualiza e mostra o tempo total do video
function AtualizaTempoTotal(e:MetadataEvent){
	ResizeVideo(e.info.width, e.info.height);
	var tempoTotal = String(e.info.duration);
	var duracaoTempo:String = (tempoTotal > 3600 ? Math.floor(tempoTotal / 3600) + ":" : "") + (tempoTotal % 3600 < 600 ? "0" : "") + Math.floor(tempoTotal % 3600/60) + ":" + (tempoTotal % 60 < 10 ? "0":"") + Math.floor(tempoTotal % 60);
	Controles.infoVideo.txt_total.text = duracaoTempo;
}
//Atualiza e mostra o tempo corrido do video
function AtualizaTempoCorrido(e:Event){
	var tempoCorridos = String(Controles.video.playheadTime * 10 / 5 / 2);
	var mostraTempo:String = (tempoCorridos > 3600 ? Math.floor(tempoCorridos / 3600) + ":" : "") + (tempoCorridos % 3600 < 600 ? "0" : "") + Math.floor(tempoCorridos % 3600/60) + ":" + (tempoCorridos % 60 < 10 ? "0":"") + Math.floor(tempoCorridos % 60);
	Controles.infoVideo.txt_time.text = mostraTempo;
}

//SoundMixer.computeSpectrum - Equalizador
var ba:ByteArray = new ByteArray();
//Cria um Sprite
var gr:Sprite = new Sprite();
sp.addChild(gr);

//máscara para o equalizador
gr.cacheAsBitmap = true;
mask_gr.cacheAsBitmap = true;
gr.mask = mask_gr;

var Mtime:Timer = new Timer(70);
Mtime.addEventListener(TimerEvent.TIMER, Equalizador);
Mtime.start();

//função Equalizador
function Equalizador(e:TimerEvent){
	SoundMixer.computeSpectrum(ba, true, 0);
	var i:int;
	//tamanho do width(Largura) das barras;
	var w:uint = 4;
	gr.graphics.clear();
	//tamanho e cor da linha;
	gr.graphics.lineStyle(0, 0x222222);
	//cor das barras;
	gr.graphics.beginFill(0x3079ED);
	
	for (i=0; i<94; i+=w){
		var t:Number = ba.readFloat();
		var n:Number = (t * 22);
		gr.graphics.drawRect(i, 0, w, -n);
	}
}